INDEX

Affiche le contenu d'une cellule définie par un décalage de ligne et de colonne.

Exemples

Créer une copie

Nom de l'invité	Régime alimentaire	Invitation envoyée	Numéro de table
David	Végétarien	Non	3
Ben	Aucun	Non	5
david	Aucun	Oui	1
Nancy	Aucun	Non	4
Marie	Végétarien	Oui	2

 

Formule	Résultat de la formule
=INDEX(A2:D6, 2, 1)	Ben
=INDEX(A2:D6, 4, 4)	4
=INDEX(A2:D6,1,1)	David
=INDEX(A1:D6, 6, 2)	Végétarien

 

Formule	Résultat de la formule
=INDEX(A2:D6, 2, 0)	Ben	Aucun	Non	5

 

Formule	Résultat de la formule
=INDEX(A2:D6, 0, 4)	3
	5
	1
	4
	2

Affiche la ou les cellules trouvées par valeur d'index dans la plage référencée.

Exemple d'utilisation

INDEX(A1:C20, 5, 1)

Syntaxe

INDEX(référence [ligne], [colonne])

• référence : plage de cellules dans laquelle les valeurs sont affichées.

• ligne – [FACULTATIF – 0 par défaut] : index de la ligne à afficher dans la plage de cellules de référence.

• colonne – [FACULTATIF – 0 par défaut] : index de la colonne à afficher dans la plage de cellules de référence.

Utiliser INDEX et EQUIV

Vous pouvez utiliser les fonctions INDEX et EQUIV ensemble pour effectuer des recherches plus avancées et dynamiques.

• Astuce : Vous pouvez utiliser RECHERCHEV lorsque la valeur de recherche se trouve à gauche de l'attribut que vous souhaitez afficher. Les fonctions INDEX et EQUIV peuvent s'utiliser quel que soit l'emplacement de la valeur de recherche dans l'ensemble de données.

Nom de l'invité	Régime alimentaire	Invitation envoyée	Numéro de table
David	Végétarien	Non	3
Ben	Aucun	Non	5
david	Aucun	Oui	1
Nancy	Aucun	Non	4
Marie	Végétarien	Oui	2

 

Objectif	Formule	Résultat de la formule	Commentaire
Trouver le régime alimentaire de Marie	=RECHERCHEV("Marie", A1:D6, 2, faux)	Végétarien	L'index et la clé de recherche sont codés en dur.
Trouver le régime alimentaire de Marie	=INDEX(A1:D6, EQUIV("Marie", A1:A6, 0), 2)	Végétarien	Le numéro de ligne est dynamique et le numéro de colonne, codé en dur.
Trouver le régime alimentaire de Marie	=INDEX(A1:D6, EQUIV("Marie", A1:A6, 0), EQUIV("Régime alimentaire", A1:D1, 0))	Végétarien	Les numéros de ligne et de colonne sont dynamiques
Trouver qui est à la table 2	Impossible avec la fonction RECHERCHEV	N/A	Vous ne pouvez utiliser RECHERCHEV que lorsque la valeur de recherche se trouve à gauche de l'attribut que vous souhaitez afficher
Trouver qui est à la table 2	=INDEX(A1:D6, EQUIV(2, D1:D6, 0), EQUIV("Nom de l'invité", A1:D1, 0))	Marie	INDEX et EQUIV peuvent s'utiliser quel que soit l'emplacement de la valeur de recherche par rapport à l'attribut que vous souhaitez afficher.

Voir également

EQUIV : Affiche la position relative d'un élément de plage correspondant à une valeur indiquée.

DECALER : Affiche une référence à une plage déplacée d'un certain nombre de lignes et de colonnes à partir d'une référence de cellule de début.

Remarques

• Si vous définissez la ligne ou la colonne sur 0, INDEX affiche le tableau de valeurs pour la colonne ou la ligne entière, respectivement.